ESP32-WROOM-32EのWireでSHT35の情報を取得

こんにちは、ENGかぴです。

Arduino環境ではWireライブラリを使うと簡単にI2C通信が実現できます。SHT35-DISは温湿度センサーで測定レンジが-40℃から+125℃と広いのが特徴です。Wireでセンサー情報を取得する方法をまとめました。

ESP32-WROOM-32E開発ボード（秋月電子）を使用しArduino IDEで開発を行います。また、AE-SHT35（秋月電子）を使用しています。

ESP32-WROOM-32Eを使って動作確認したことをまとめています。

SHT35-DISの情報を取得する
1. Wire（I2C通信）を実装する
  1. Wireによるデータ送信の例
  2. Wireによるデータ受信の例
2. SHT35-DISの測定とデータ取得
動作確認
ソースコード全体
関連リンク

SHT35-DISの情報を取得する

SHT35-DISはSENSIRION社の高精度温湿度センサーであり通信方式はI2CであるためWireライブラリを使用します。ESP32-WROOM-32Eから測定コマンド及びリードを送信することでSHT35-DISからデータを取得できます。

Wire（I2C通信）を実装する

#include <Wire.h>

void setup() {
  Wire.begin();

  //Wire.begin(SDA, SCL, 10000); 任意のピンを使用する場合
}

最初に「Wire.h」をインクルードする必要があります。Wire.begin()でI2Cの条件を初期化してスタートします。引数にSDA、SCLに指定したいピン及び通信速度を指定します。引数を指定しない場合の初期値はシルク印刷番号ではSDAが21番、SCLが22番、通信速度は100kHzになります。

任意のピンでのソフトウェアWireでも動作しますが動作が安定しないことが多いためI2C機能を搭載しているピンを使用することをお勧めします。

PR：わからないを放置せず、あなたにあった最低限のスキルを身に着けるコツを教えるテックジム　「書けるが先で、理解が後」を体験しよう！

Wireによるデータ送信の例

ArduinoのWireを組み込んで送信する例を示します。

void Sht35Measure(uint8_t dev_id,uint8_t* cmd, uint16_t len){

  Wire.beginTransmission(dev_id); //スレーブが存在するか確認
  byte error = Wire.endTransmission();
  if( error == 0){ //スレーブが存在する場合下の処理
    Wire.beginTransmission(dev_id);
    for( uint16_t i=0; i < len; i++ ){
      Wire.write(*cmd); //lenサイズ分だけデータを書き込む
      ++cmd;
    }
    Wire.endTransmission(); //ストップ・コンディションの発行
  }
  else{
    //スレーブが存在しない場合の処理
  }
}

最初にスレーブが存在するかを確認するためにbeginTransmisson()の引数にスレーブアドレスを指定しています。endTransmisson()でスレーブアドレスが送出され戻り値が0であれば存在するアドレスとなります。

スレーブが存在する場合はbeginTransmisson()でスレーブアドレスを指定します。write()は送信するデータを一時的に保管（キューイング）するために使用します。引数に送信するデータを指定します。例ではlenサイズ分データを書き込む準備をしています。

endTransmission() でスレーブアドレスを含めてキューイングしたデータをスレーブに送信します。

Wireによるデータ受信の例

ArduinoのWireを組み込んでデータ受信する例を示します。

bool Sht35GetData(uint8_t dev_id,uint8_t* reg_data, uint16_t len){
  bool  ret = false;

  Wire.beginTransmission(dev_id); //スタート・コンディションの発行
  byte error = Wire.endTransmission();
  if( error == 0){ //スレーブが存在する場合下の処理
    if( Wire.requestFrom(dev_id, len) == len ){
      for( uint16_t i=0; i < len; i++ ){
        *reg_data = Wire.read(); //len分だけデータをリードする
        ++reg_data;
      }
      ret = true;
    }
  }
  else{
    //スレーブが存在しない場合の処理
  }
  return ret;
}

送信時と同様に初めにスレーブが存在を確認します。スレーブが存在する場合は requestFrom ()を使用してスレーブアドレスに対して指定するバイト数を要求します。

第1引数にスレーブアドレスを指定し、第2引数に要求するバイト数を指定します。戻り値はスレーブから読み込んだバイト数となります。

要求したデータ数が準備できていることを確認しrequestFrom()で要求したデータをread()を使用して読み込み変数に格納します。

requestFrom()でデータを要求した場合はendTransmission()の発行は必要ありません。

PR：RUNTEQ（ランテック）- マイベスト３年連続1位を獲得した実績を持つWebエンジニア養成プログラミングスクール

SHT35-DISの測定とデータ取得

SHT35-DISの計測をシングルショットモード（クロックストレッチを有効）で行いデータの取得する方法を説明します。取得したデータの健全性を確認するCRC8の計算方法について説明します。

コマンドを送信する

SHT35-DISはコマンドを16ビット長になるように送信（Write）する必要があります。シングルショットモード（繰り返し精度レベル：高）をクロックストレッチを有効にする場合は0x2c06がコマンドになります。

クロックストレッチを有効にすると測定中にSCLの信号レベルがLOWに維持されるためSCLがHighに復帰するタイミングで測定が完了したことが確認できます。

Wireによるデータ送信の例で説明したSht35Measure()を使用して測定を開始します。

#define SLAVE_ADRS 0x45 //ADRオープン時のアドレス
uint8_t singleshot[2] = { 0x2C, 0x06};　//シングルショットモードでクロックストレッチ有効
//使用例
Sht35Measure(SLAVE_ADRS, &singleshot[0], sizeof(singleshot));

Sht35Measure ()の第1引数にスレーブのアドレス、第2引数に送信する値を格納しているアドレス、第3引数に送信するサイズを指定します。

測定データを取得する

Wireによるデータ受信の例で説明したSht35GetData()を使用してデータを取得します。

uint8_t rxdata[6];
//使用例
Sht35GetData(SLAVE_ADRS, &rxdata[0], sizeof(rxdata));

Sht35GetData ()の第1引数にスレーブのアドレス、第2引数に受信した測定データを格納するアドレス、第3引数に受信するデータサイズを指定します。

受信データは温度データ16ビットと温度データのCRC、湿度データ16ビットと湿度データのCRCの合計6バイトを受信します。受信した測定データのCRCの計算結果と取得したCRCの結果を比較して一致したとき有効なデータとして採用します。CRC計算の条件がデータシートに記載されています。

uint8_t Crc8Calc(uint8_t *data, uint8_t sz ){
  uint8_t crc = 0xFF;
  uint8_t i,j;
    
  for( i = 0; i < sz; i++){
    crc ^= *data;
        
    for( j = 0; j < 8; j++ ){
      if( crc & 0x80 ){
        crc = ( crc << 1 ) ^ POLYNOMIAL;
      }
      else{
        crc = crc << 1;
      }
    }
    ++data;
  }
  return crc;
}

CRC-8の計算方法は初期値と1バイト目のバイトデータのXORを計算します。この値を8ビット分左にシフトしていきますが、最上位ビットが立った時に1ビット分シフトしてからPolynomialとXORをとります。

2バイト目以降は前のバイトの結果を初期値として8ビット分シフトとXORを繰り返していき対象のデータのバイト数だけ繰り返します。

PR：スキマ時間で自己啓発！スマホで学べる人気のオンライン資格講座【スタディング】まずは気になる講座を無料で体験しよう！

測定データの換算

SHT35-DISから受信した測定データは16ビットの符号なしの整数型の数値ですが温湿度に換算する必要があります。測定データの換算方法はデータシートに記載されています。

受信したデータは1バイトずつ取得しているため2バイトデータに置き換えた後換算を行います。小数点以下が出るためfloatを使用します。

uint16_t tempHex;
uint16_t humiHex;
float temp;
float humi;

tempHex = ((uint16_t)rxdata[0] << 8) | rxdata[1]; //2バイトデータに変換
humiHex =((uint16_t)rxdata[3] << 8) | rxdata[4]; //2バイトデータに変換
temp = (tempHex / 65535.0) * 175 - 45; //温度に換算
humi = (humiHex / 65535.0) * 100.0; //湿度に換算

PR：アクセンチュアの転職なら【コンサルアクシスコンサルティング】